如何在 SPSS 中进行预测变量的中心化？

By Ruben Geert van den Berg under Regression

另请参阅 SPSS 调节回归教程。

SPSS 预测变量中心化 - 变量视图示例

为了在 多元回归 中检验 调节 效应，我们首先对预测变量进行中心化（Mean Centering）：变量中心化是指从每个单独的分数中减去其平均值。这样做之后，变量的平均值将恰好为零，但不会以其他方式受到影响：其标准差、偏度、分布形状和其他所有内容都保持不变。 在对预测变量进行中心化之后，我们只需将它们相乘，以便将交互预测变量添加到我们的数据中。在此之前进行中心化有两个好处：

  • 它往往会减少多重共线性，尤其是在交互效应及其组成的主要效应之间；
  • 它可以使我们的 b 系数 更容易解释。

我们将在后续教程中介绍包含调节交互作用的完整回归分析。现在，我们将重点介绍如何对预测变量进行中心化并计算（调节）交互预测变量。

中心化示例 I - 单个变量

我们现在将在 course_evaluation.sav 中对一些变量进行中心化。其 变量视图 的一部分如下所示。

SPSS 变量中心化数据视图

我们从 q2（“您如何评价本课程的老师？”）开始。我们首先使用 AGGREGATE 命令将此变量的平均值作为新变量添加到我们的数据集中。下面的 语法 正是这样做的。不要在这里纠结于任何菜单，因为它只会减慢你的速度。

用于将变量的平均值添加到我们数据的语法

***创建新变量，保存原始变量的平均值。
AGGREGATE OUTFILE * MODE ADDVARIABLES
/mean_q2 = MEAN(q2).

结果

SPSS 中心化变量平均值添加到数据集

q2 的平均值似乎是 3.88。很抱歉这里使用逗号作为小数点分隔符。我在运行此示例时将我的区域设置设置为荷兰语。但在 SPSS 中，你看到的不是你得到的。如果我们选择一个单元格，我们会看到确切的平均值是 3.87978142076503。这就是为什么我们不只是从原始变量中减去 3.88 的原因——正如许多不太好的教程所建议的那样。 第二个原因是，如果我们决定先使用 FILTER、SELECT IF 或 WEIGHT 命令，我们的方法仍然可以完美地工作。 现在，第二个也是最后一个步骤是简单地使用 COMPUTE 命令从我们的原始变量中减去这个平均值。然后我们将对结果进行快速检查，我们就完成了。

从原始值中减去平均值

***从原始值中减去平均值。
COMPUTE cent_q2 = q2 - mean_q2.

***向中心化变量添加变量标签。
VARIABLE LABELS cent_q2 "您如何评价本课程的老师？(中心化)".

***检查结果。
DESCRIPTIVES q2 cent_q2.

***删除辅助变量。
DELETE VARIABLES mean_q2.

结果

SPSS 预测变量中心化检查结果

中心化后的快速检查是比较原始变量和中心化变量的一些描述性统计量：

  • 中心化变量必须具有完全零平均值；
  • 中心化变量和原始变量必须具有完全相同的标准差。

如果这两个检查都成立，我们可以非常确信我们的中心化已正确完成。

中心化示例 II - 多个变量

在实际分析中，您可能会中心化至少 2 个变量，因为这是创建调节预测变量的最小值。您可以通过为每个变量重复前面的步骤来中心化多个变量。 但是，如果我们可以通过以下方式加快速度，则可以更快地完成此操作：

  • 将多个变量放入单个 AGGREGATE 命令中，
  • 使用 DO REPEAT 从原始分数中减去每个变量的平均值，以及
  • 不创建保存平均值的辅助变量。

下面的语法正是这样做的。

语法示例 - 中心化多个变量

***向数据集添加保存平均值的新变量。
AGGREGATE OUTFILE * MODE ADDVARIABLES
/cent_q3 TO cent_q6 = MEAN(q3 TO q6).

***从原始变量中减去平均值。
DO REPEAT #ori = q3 TO q6 / #cent = cent_q3 TO cent_q6.
COMPUTE #cent = #ori - #cent.
END REPEAT.

***向中心化变量添加变量标签。
VARIABLE LABELS cent_q3 "您如何评价本课程的讲座？(中心化)".
VARIABLE LABELS cent_q4 "您如何评价本课程的作业？(中心化)".
VARIABLE LABELS cent_q5 "您如何评价我们发布的学习资源（例如教学大纲和讲义）？(中心化)".
VARIABLE LABELS cent_q6 "您如何评价我们未发布的学习资源（例如书籍）？(中心化)".

***检查结果。
DESCRIPTIVES q3 cent_q3 q4 cent_q4 q5 cent_q5 q6 cent_q6.

结果

SPSS 预测变量中心化检查所有结果

将调节预测变量添加到我们的数据

虽然超出了本教程的范围，但创建调节预测变量就像将 2 个中心化预测变量相乘一样简单。

***将中心化预测变量相乘以创建交互预测变量。
COMPUTE int_1 = cent_q3 * cent_q4.

***将简短但清晰的变量标签应用于交互预测变量。
VARIABLE LABELS int_1 "交互作用：讲座评分 * 作业评分（均中心化）".

为了检验 q3 是否调节了 q4 对某些结果变量的影响，我们只需将此交互预测变量及其 2 个中心化(!) 构成要素 cent_q3、cent_q4 输入到我们的回归方程中。 我们很快将在后续教程中介绍对（更合适的数据）的完整分析。 感谢阅读！